all: refactor to follow RFC140

pkgs/by-name/al/alacritty-ligatures/package.nix

@@ -0,0 +1,55 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+
+, alacritty
+
+, fontconfig
+, freetype
+, libglvnd
+, libxcb
+}:
+
+alacritty.overrideAttrs (oldAttrs: rec {
+  pname = "${oldAttrs.pname}-ligatures";
+  version = "0.7.2.20210209.g3ed0430";
+
+  src = fetchFromGitHub {
+    owner = "zenixls2";
+    repo = "alacritty";
+    fetchSubmodules = true;
+    rev = "3ed043046fc74f288d4c8fa7e4463dc201213500";
+    sha256 = "1dGk4ORzMSUQhuKSt5Yo7rOJCJ5/folwPX2tLiu0suA=";
+  };
+
+  cargoDeps = oldAttrs.cargoDeps.overrideAttrs (lib.const {
+    name = "${pname}-${version}-vendor.tar.gz";
+    inherit src;
+    outputSha256 = "pONu6caJmEKnbr7j+o9AyrYNpS4Q8OEjNZOhGTalncc=";
+  });
+
+  ligatureInputs = [
+    fontconfig
+    freetype
+    libglvnd
+    stdenv.cc.cc.lib
+    libxcb
+  ];
+
+  preferLocalBuild = true;
+
+  buildInputs = (oldAttrs.buildInputs or [ ]) ++ ligatureInputs;
+
+  # HACK: One of the ligature libraries required the C++ stdlib at runtime,
+  # and I can't work out a better way to push it to the RPATH.
+  postInstall = lib.optional (!stdenv.isDarwin) ''
+    patchelf \
+      --set-rpath ${lib.makeLibraryPath ligatureInputs}:"$(patchelf --print-rpath $out/bin/alacritty)" \
+      $out/bin/alacritty
+  '';
+
+  meta = oldAttrs.meta // {
+    description = "Alacritty with ligature patch applied";
+    homepage = "https://github.com/zenixls2/alacritty/tree/ligature";
+  };
+})

pkgs/by-name/am/amdgpu-fan/package.nix

@@ -0,0 +1,34 @@
+{ lib
+, fetchFromGitHub
+
+, python3Packages
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "amdgpu-fan";
+  version = "0.0.6";
+
+  src = fetchFromGitHub {
+    repo = pname;
+    owner = "chestm007";
+    rev = version;
+    sha256 = "1ngfrk6agk8wz0q9426lwrqhbgxc98hrsv0kn6wgz25j1rv9332b";
+  };
+
+  propagatedBuildInputs = with python3Packages; [
+    numpy
+    pyyaml
+  ];
+
+  patchPhase = ''
+    substituteInPlace setup.py \
+      --replace PROJECTVERSION "${version}"
+  '';
+
+  meta = with lib; {
+    description = "Fan controller for AMD graphics cards running the amdgpu driver on Linux";
+    homepage = "https://github.com/chestm007/amdgpu-fan";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/at/atlauncher/package.nix

@@ -0,0 +1,46 @@
+{ stdenv
+, lib
+, fetchurl
+, makeWrapper
+, jdk17
+, udev
+, xorg
+}:
+
+stdenv.mkDerivation rec {
+  pname = "atlauncher";
+  version = "3.4.33.1";
+
+  src = fetchurl {
+    url = "https://github.com/ATLauncher/ATLauncher/releases/download/v${version}/ATLauncher-${version}.jar";
+    hash = "sha256-YfTo3Vp4ACQPQJWCujpAv8J0i2FuG5MLaIjNdBPN1Ns=";
+  };
+
+  dontUnpack = true;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/java
+    cp $src $out/share/java/ATLauncher.jar
+    makeWrapper ${jdk17}/bin/java $out/bin/atlauncher \
+      --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ xorg.libXxf86vm udev ]}" \
+      --add-flags "-jar $out/share/java/ATLauncher.jar" \
+      --add-flags "--working-dir \''${XDG_DATA_HOME:-\$HOME/.local/share}/ATLauncher" \
+      --add-flags "--no-launcher-update"
+  '';
+
+  meta = {
+    description = "Minecraft launcher";
+    longDescription = ''
+      ATLauncher is a Launcher for Minecraft which integrates multiple different
+      ModPacks to allow you to download and install ModPacks easily and quickly.
+    '';
+    sourceProvenance = [
+      (lib.sourceTypes.binaryBytecode or { shortName = "binaryBytecode"; isSource = false; })
+    ];
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.all;
+    homepage = "https://atlauncher.com/";
+  };
+}

pkgs/by-name/ca/cardboard/0001-use-system-dependencies.patch

@@ -0,0 +1,62 @@
+diff --git a/cardboard/meson.build b/cardboard/meson.build
+index b236f71..a90f230 100644
+--- a/cardboard/meson.build
++++ b/cardboard/meson.build
+@@ -4,24 +4,15 @@ xkbcommon = dependency('xkbcommon')
+ xcb = dependency('xcb', required: get_option('xwayland'))
+ 
+ wlroots_version = '>=0.10.0'
+-wlroots_proj = subproject(
++wlroots = dependency(
+   'wlroots',
+-  default_options: ['examples=false'],
+   required: true,
+   version: wlroots_version,
+ )
+ 
+-wlroots = wlroots_proj.get_variable('wlroots')
+-wlroots_conf = wlroots_proj.get_variable('conf_data')
+-wlroots_has_xwayland = wlroots_conf.get('WLR_HAS_XWAYLAND') == 1
++have_xwayland = xcb.found()
+ 
+-if get_option('xwayland').enabled() and not wlroots_has_xwayland
+-    error('Cannot enable Xwayland support in cardboard: wlroots has been built without Xwayland support')
+-endif
+-have_xwayland = xcb.found() and wlroots_has_xwayland
+-
+-expected_proj = subproject('expected', required: true)
+-expected = expected_proj.get_variable('expected_dep')
++expected = dependency('tl-expected', required: true, method: 'cmake', modules: ['tl::expected'])
+ 
+ conf_data = configuration_data()
+ conf_data.set10('HAVE_XWAYLAND', have_xwayland)
+diff --git a/cutter/meson.build b/cutter/meson.build
+index f1260a4..1485f37 100644
+--- a/cutter/meson.build
++++ b/cutter/meson.build
+@@ -1,6 +1,5 @@
+ # SPDX-License-Identifier: GPL-3.0-only
+-expected_proj = subproject('expected', required: true)
+-expected = expected_proj.get_variable('expected_dep')
++expected = dependency('tl-expected', required: true, method: 'cmake', modules: ['tl::expected'])
+ 
+ executable(
+     'cutter',
+diff --git a/libcardboard/meson.build b/libcardboard/meson.build
+index 89698fe..3ac8115 100644
+--- a/libcardboard/meson.build
++++ b/libcardboard/meson.build
+@@ -1,11 +1,9 @@
+ # SPDX-License-Identifier: GPL-3.0-only
+ libcardboard_inc = include_directories('include')
+ 
+-expected_proj = subproject('expected', required: true)
+-expected = expected_proj.get_variable('expected_dep')
++expected = dependency('tl-expected', required: true, method: 'cmake', modules: ['tl::expected'])
+ 
+-cereal_proj = subproject('cereal', required: true)
+-cereal = cereal_proj.get_variable('cereal_dep')
++cereal = dependency('cereal', required: true, method: 'cmake')
+ 
+ sources = files(
+     'src/command_protocol.cpp',

pkgs/by-name/ca/cardboard/package.nix

@@ -0,0 +1,68 @@
+{ stdenv
+, lib
+, fetchFromGitLab
+, cereal
+, cmake
+, libGL
+, libX11
+, libinput
+, libxkbcommon
+, meson
+, ninja
+, pixman
+, pkg-config
+, tl-expected
+, wayland
+, wayland-protocols
+, wlroots
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cardboard";
+  version = "20210120.g7b15613";
+
+  src = fetchFromGitLab {
+    owner = "cardboardwm";
+    repo = "cardboard";
+    rev = "7b15613e6e1222a6a83d69a2e5da2810dfb45522";
+    sha256 = "044sb0lv1gcywpdncvlv7npxvbsqcc1mwpk0f6i73dinchdz7gmq";
+  };
+
+  patches = [
+    ./0001-use-system-dependencies.patch
+  ];
+
+  # CMake likes to own the configurePhase, but we only need it for dependency
+  # discovery. Remove it.
+  configurePhase = "mesonConfigurePhase";
+
+  nativeBuildInputs = [
+    cmake
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    cereal
+    libGL
+    libX11
+    libinput
+    libxkbcommon
+    pixman
+    tl-expected
+    wayland
+    wayland-protocols
+    wlroots
+  ];
+
+  passthru.providedSessions = [ "cardboard" ];
+
+  meta = with lib; {
+    description = "Scrollable tiling Wayland compositor designed with laptops in mind";
+    homepage = "https://gitlab.com/cardboardwm/cardboard";
+    license = licenses.gpl3;
+    platforms = wlroots.meta.platforms;
+    broken = true;
+  };
+}

pkgs/by-name/cu/cura5/package.nix

@@ -0,0 +1,39 @@
+{ stdenv
+, fetchurl
+, writeScriptBin
+, appimageTools
+}:
+
+let
+  pname = "cura5";
+  version = "5.4.0";
+  name = "${pname}-${version}";
+
+  cura5 = appimageTools.wrapType2 {
+    inherit pname version;
+    src = fetchurl {
+      url = "https://github.com/Ultimaker/Cura/releases/download/${version}/Ultimaker-Cura-${version}-linux-modern.AppImage";
+      hash = "sha256-QVv7Wkfo082PH6n6rpsB79st2xK2+Np9ivBg/PYZd74=";
+    };
+    extraPkgs = _: [ ];
+  };
+  script = writeScriptBin pname ''
+    #!${stdenv.shell}
+    # AppImage version of Cura loses current working directory and treats all paths relateive to $HOME.
+    # So we convert each of the files passed as argument to an absolute path.
+    # This fixes use cases like `cd /path/to/my/files; cura mymodel.stl anothermodel.stl`.
+
+    args=()
+    for a in "$@"; do
+      if [ -e "$a" ]; then
+        a="$(realpath "$a")"
+      fi
+      args+=("$a")
+    done
+    exec "${cura5}/bin/${name}" "''${args[@]}"
+  '';
+in
+script // {
+  inherit name pname version;
+  meta.platforms = [ "x86_64-linux" ];
+}

pkgs/by-name/li/libhl/fix-link.patch

@@ -0,0 +1,13 @@
+diff --git a/Makefile.in b/Makefile.in
+index 97b3901..4191da6 100644
+--- a/Makefile.in
++++ b/Makefile.in
+@@ -69,7 +69,7 @@ static: objects
+ 
+ .PHONY: shared
+ shared: objects
+-	./libtool --mode=link $(CC) $(LIBS) $(LDFLAGS) -Wc,$(SHAREDFLAGS) -o $(builddir)/libhl.$(SHAREDEXT) $(builddir)/*.o
++	./libtool --mode=link $(CC) $(LIBS) $(LDFLAGS) -Wc,$(SHAREDFLAGS) -o $(builddir)/libhl.$(SHAREDEXT) .libs/*.o
+ 
+ %.o : $(srcdir)/src/%.c
+ 	./libtool --mode=compile $(CC) -c $(CFLAGS) $< -o $(builddir)/$@

pkgs/by-name/li/libhl/package.nix

@@ -0,0 +1,35 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+
+, autoreconfHook
+}:
+
+stdenv.mkDerivation rec {
+  pname = "libhl";
+  version = "3.1";
+
+  src = fetchFromGitHub {
+    owner = "xant";
+    repo = pname;
+    rev = "${pname}-${version}";
+    sha256 = "05mrp5rmki0wghdpmcgvsi8lqhfshifbmhp1qlkd89fb2srq91lf";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+  ];
+
+  patches = [ ./fix-link.patch ];
+
+  preInstall = ''
+    mkdir -p $out/include $out/lib
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/xant/libhl";
+    description = "Simple and fast C library implementing a thread-safe API to manage hash-tables, linked lists, lock-free ring buffers and queues ";
+    license = licenses.lgpl3;
+    platforms = platforms.all;
+  };
+}

pkgs/by-name/pa/pam_gnupg/package.nix

@@ -0,0 +1,35 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+
+, autoreconfHook
+, gnupg
+, pam
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pam-gnupg";
+  version = "0.1";
+
+  src = fetchFromGitHub {
+    owner = "cruegge";
+    repo = "pam-gnupg";
+    rev = "v${version}";
+    sha256 = "0b70mazyvcbg6xyqllm62rwhbz0y94pcy202db1qyy4w8466bhsw";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    gnupg
+  ];
+  buildInputs = [ pam ];
+
+  configureFlags = [ "--with-moduledir=\${out}/lib/security" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/cruegge/pam-gnupg";
+    description = "Unlock GnuPG keys on login";
+    license = licenses.gpl3;
+    platforms = pam.meta.platforms;
+  };
+}

pkgs/by-name/ps/psst/package.nix

@@ -0,0 +1,72 @@
+{ lib
+, fetchFromGitHub
+, rustPlatform
+
+, pkg-config
+, alsaLib
+, dbus
+, openssl
+
+  # GUI
+, withGui ? true
+, copyDesktopItems
+, makeDesktopItem
+, gtk3
+}:
+
+let
+  inherit (lib) optional optionals;
+in
+
+assert withGui -> gtk3.meta.available;
+
+rustPlatform.buildRustPackage rec {
+  pname = "psst";
+  version = "20221012.d70ed81";
+  src = fetchFromGitHub {
+    owner = "jpochyla";
+    repo = "psst";
+    rev = "d70ed8104533dc15bc36b989ba8428872c9b578f";
+    hash = "sha256-ZKhHN0ruLb6ZVKkrKv/YawRsVop6SP1QF/nrtkmA8P8=";
+    fetchSubmodules = true;
+  };
+  cargoSha256 = "sha256-zH6+EV78FDVOYEFXk0f54pH2Su0QpK1I0bHqzIiMdBo=";
+
+  nativeBuildInputs = [ pkg-config ]
+    ++ optional withGui copyDesktopItems;
+
+  buildInputs = [ alsaLib dbus openssl ]
+    ++ optional withGui gtk3;
+
+  cargoBuildFlags = optionals (!withGui) [
+    "--workspace"
+    "--exclude"
+    "psst-gui"
+  ];
+
+  # Unable to exclude targets from the check phase as it doesn't respect
+  # `cargoBuildFlags`; to save from attempting to build the GUI without meaning
+  # to, don't bother checking for CLI-only builds.
+  # https://github.com/NixOS/nixpkgs/blob/77d190f10931c1d06d87bf6d772bf65346c71777/pkgs/build-support/rust/default.nix#L241
+  doCheck = withGui;
+
+  desktopItems = optionals withGui [
+    (makeDesktopItem {
+      name = pname;
+      desktopName = "psst";
+      genericName = "Spotify Player";
+      categories = [ "AudioVideo" "Audio" "Network" "Player" ];
+      comment = "Spotify client with native GUI";
+      exec = "psst-gui";
+      keywords = [ "spotify" "music" ];
+      icon = "spotify";
+      type = "Application";
+    })
+  ];
+
+  meta = with lib; {
+    description = "Fast and multi-platform Spotify client with native GUI ";
+    homepage = "https://github.com/jpochyla/psst";
+    license = licenses.mit;
+  };
+}

pkgs/by-name/sa/samrewritten/package.nix

@@ -0,0 +1,48 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, curl
+, gnumake
+, gnutls
+, gtk3
+, gtkmm3
+, pkg-config
+, yajl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "SamRewritten";
+  version = "2.1";
+
+  src = fetchFromGitHub {
+    owner = "PaulCombal";
+    repo = pname;
+    rev = "202008";
+    sha256 = "ab7903b997675b0d4d7eede15430fc5ca2736e6c25c7f95a7c97e1ce25582a1c";
+  };
+
+  nativeBuildInputs = [ gnumake pkg-config ];
+  buildInputs = [
+    curl
+    gnutls
+    gtk3
+    gtkmm3
+    yajl
+  ];
+
+  NIX_CFLAGS_LINK = "-pthread";
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  postFixup = ''
+    substituteInPlace $out/share/applications/samrewritten.desktop \
+      --replace /usr/bin/samrewritten $out/bin/samrewritten
+  '';
+
+  meta = with lib; {
+    description = "Steam Achievement Manager For Linux";
+    homepage = "https://github.com/PaulCombal/SamRewritten";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+  };
+}

pkgs/by-name/sp/spotify-ripper/fix-setup.patch

@@ -0,0 +1,24 @@
+diff --git a/setup.py b/setup.py
+index a800b3b..8967921 100755
+--- a/setup.py
++++ b/setup.py
+@@ -33,14 +33,13 @@ setup(
+     name='spotify-ripper',
+     version='2.9.1',
+     packages=find_packages(exclude=["tests"]),
+-    scripts=['spotify_ripper/main.py'],
+     include_package_data=True,
+     zip_safe=False,
+ 
+     # Executable
+     entry_points={
+         'console_scripts': [
+-            'spotify-ripper = main:main',
++            'spotify-ripper = spotify_ripper.main:main',
+         ],
+     },
+ 
+@@ -121,3 +121,2 @@ setup(
+     return True
+ 
+-create_default_dir()

pkgs/by-name/sp/spotify-ripper/package.nix

@@ -0,0 +1,73 @@
+{ lib
+, fetchFromGitHub
+
+, python3Packages
+, lame
+
+, aacSupport ? false
+, faac
+, alacSupport ? false
+, libav
+, flacSupport ? false
+, flac
+, m4aSupport ? false
+, mp4Support ? false
+, fdk-aac-encoder
+, oggSupport ? false
+, vorbisTools
+, opusSupport ? false
+, opusTools
+}:
+
+assert aacSupport -> faac.meta.available;
+assert alacSupport -> libav.meta.available;
+assert flacSupport -> flac.meta.available;
+assert m4aSupport || mp4Support -> fdk-aac-encoder.meta.available;
+assert oggSupport -> vorbisTools.meta.available;
+assert opusSupport -> opusTools.meta.available;
+
+python3Packages.buildPythonApplication rec {
+  pname = "spotify-ripper";
+  version = "20210724.5bfd3f7";
+
+  src = fetchFromGitHub {
+    owner = "ast261";
+    repo = pname;
+    rev = "5bfd3f7a52f2767b433fd315145409837a3c33f0";
+    sha256 = "sha256-LLunGzs9Mg4S00Su260b+M5w/XwS+kICl/YXQdR/cPI=";
+  };
+
+  propagatedBuildInputs = (with python3Packages; [
+    colorama
+    mutagen
+    pyspotify
+    requests
+    schedule
+    setuptools
+    spotipy
+  ]) ++ [
+    lame
+    (if flacSupport then flac else null)
+    (if alacSupport then libav else null)
+    (if aacSupport then faac else null)
+    (if (m4aSupport || mp4Support) then fdk-aac-encoder else null)
+    (if oggSupport then vorbisTools else null)
+    (if opusSupport then opusTools else null)
+  ];
+
+  # Remove impure executables.
+  patches = [ ./fix-setup.patch ];
+
+  meta = with lib; {
+    description = "Rip Spotify URIs to audio files, including ID3 tags and cover art";
+    longDescription = ''
+      Spotify-ripper is a small ripper script for Spotify that rips Spotify URIs
+      to audio files and includes ID3 tags and cover art. By default
+      spotify-ripper will encode to MP3 files, but includes the ability to rip
+      to WAV, FLAC, Ogg Vorbis, Opus, AAC, and MP4/M4A.
+    '';
+    homepage = "https://github.com/hbashton/spotify-ripper";
+    # spotify-ripper itself is MIT, but the upstream libspotify is unfree.
+    license = licenses.unfree;
+  };
+}

pkgs/by-name/yt/ytarchive/package.nix

@@ -0,0 +1,38 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, python3
+, ffmpeg
+}:
+
+stdenv.mkDerivation rec {
+  pname = "ytarchive";
+  version = "0.2.2+0304577";
+
+  src = fetchFromGitHub {
+    owner = "Kethsar";
+    repo = "ytarchive";
+    # NOTE: Last revision where it was written in Python, so don't change
+    #   without rewriting the derivation.
+    rev = "030457749d6c8d1d62240bfbad659326f3cd3a30";
+    hash = "sha256-mvmdkxZxlEbWc7GR8LfyxTJOeEhjCoYyeatDx8l1uhM=";
+  };
+
+  propagatedBuildInputs = [
+    python3
+    ffmpeg
+  ];
+
+  phases = [ "unpackPhase" "installPhase" "fixupPhase" ];
+
+  installPhase = ''
+    install -Dm00755 ytarchive.py $out/bin/ytarchive
+  '';
+
+  meta = with lib; {
+    description = "Garbage Youtube livestream downloader";
+    homepage = "https://github.com/Kethsar/ytarchive";
+    license = licenses.mit;
+    platforms = python3.meta.platforms;
+  };
+}

pkgs/by-name/zs/zsh-z/package.nix

@@ -0,0 +1,35 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, installShellFiles
+
+, zsh
+}:
+
+stdenv.mkDerivation {
+  pname = "zsh-z";
+  version = "20210117.g289a4a7";
+
+  src = fetchFromGitHub {
+    owner = "agkozak";
+    repo = "zsh-z";
+    rev = "289a4a7208db9b1778cba71c58fed46dbcea3bc7";
+    sha256 = "016prpavxdzjg372y2700rczdgzjb53bqz5mxjgmvrvjxwj69cf0";
+  };
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  propogatedBuildInputs = [ zsh ];
+
+  installPhase = ''
+    install -D zsh-z.plugin.zsh $out/share/zsh-z/zsh-z.zsh
+    installShellCompletion --zsh _zshz
+  '';
+
+  meta = with lib; {
+    description = ''Jump quickly to directories that you have visited "frecently." A native ZSH port of z.sh.'';
+    homepage = "https://github.com/agkozak/zsh-z";
+    license = licenses.mit;
+    platforms = zsh.meta.platforms;
+  };
+}