all: initial port from private config

pkgs/applications/editors/jetbrains/build-plugin.nix

@@ -0,0 +1,30 @@
+{ stdenv
+, fetchzip
+, jetbrainsPlatforms
+}:
+
+{ pluginId
+, pname
+, version
+, versionId
+, sha256
+, filename ? "${pname}-${version}.zip"
+}:
+
+stdenv.mkDerivation {
+  inherit pname version jetbrainsPlatforms;
+
+  src = fetchzip {
+    inherit sha256;
+    url = "https://plugins.jetbrains.com/files/${toString pluginId}/${toString versionId}/${filename}";
+  };
+
+  installPhase = ''
+    mkdir $out
+    cp -r * $out/
+  '';
+
+  meta = {
+    homepage = "https://plugins.jetbrains.com/plugin/${pluginId}-${stdenv.lib.toLower pname}";
+  };
+}

pkgs/applications/editors/jetbrains/builder.nix

@@ -0,0 +1,33 @@
+{ lib
+}: self:
+
+with lib;
+
+package:
+pluginsFun:
+
+let
+  plugins =
+    if isFunction pluginsFun
+    then pluginsFun self
+    else pluginsFun;
+
+  info = builtins.parseDrvName package.name;
+
+  badPlugins = filter (p: ! elem info.name p.jetbrainsPlatforms) plugins;
+  errorMsg = "plugins [ ${toString (map (p: p.name) badPlugins)} ] are not available for platform ${info.name}";
+in
+
+assert assertMsg (length badPlugins == 0) errorMsg;
+
+package.overrideAttrs (oldAttrs: {
+  # FIXME: versioning: could just expose upstream
+  name = "${info.name}-with-plugins-${info.version}";
+
+  inherit plugins;
+  installPhase = oldAttrs.installPhase + ''
+    for plugin in $plugins; do
+      ln -s "$plugin" "$out/$name/plugins/$(basename $plugin)"
+    done
+  '';
+})

pkgs/applications/editors/jetbrains/common-plugins.nix

@@ -0,0 +1,44 @@
+{ callPackage }:
+let
+  mkPlugin = callPackage ./build-plugin.nix {
+    jetbrainsPlatforms = [
+      "clion"
+      "datagrip"
+      "goland"
+      "idea-community"
+      "idea-ultimate"
+      "phpstorm"
+      "pycharm-community"
+      "pycharm-professional"
+      "rider"
+      "ruby-mine"
+      "webstorm"
+    ];
+  };
+in
+{
+  ideavim = mkPlugin {
+    pname = "IdeaVim";
+    version = "0.57";
+    pluginId = 164;
+    versionId = 85009;
+    sha256 = "1rwfwj0b0nwi7jxhzxk1r0xc190nf4i3b59i0zknpmgb4yc5clzw";
+  };
+
+  checkstyle-idea = mkPlugin {
+    pname = "CheckStyle-IDEA";
+    version = "5.42.0";
+    pluginId = 1065;
+    versionId = 95757;
+    sha256 = "0sji3649n5zz84dlidqaklipq6vaiafxsvg0gzy3j59mvkz6dk14";
+  };
+
+  google-java-format = mkPlugin rec {
+    pname = "google-java-format";
+    version = "1.7.0.4";
+    pluginId = 8527;
+    versionId = 83164;
+    sha256 = "1pmnn1ksiv44kdga53gi3psrm2sva4bqrxizagbr0if2n0rrvgii";
+    filename = "${pname}.zip";
+  };
+}

pkgs/applications/editors/jetbrains/idea-plugins.nix

@@ -0,0 +1,15 @@
+{ callPackage }:
+let
+  mkPlugin = callPackage ./build-plugin.nix {
+    jetbrainsPlatforms = [ "idea-community" "idea-ultimate" ];
+  };
+in
+{
+  spring-assistant = mkPlugin {
+    pname = "intellij-spring-assistant";
+    version = "0.12.0";
+    pluginId = 10229;
+    versionId = 44968;
+    sha256 = "13cglywzhb4j0qj0bs2jwaz2k8pxrxalv35wgkmgkxr635bxmwsj";
+  };
+}