all: initial port from private config

pkgs/tools/misc/amdgpu-fan/default.nix

@@ -0,0 +1,29 @@
+{ stdenv
+, fetchFromGitHub
+
+, python3Packages
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "amdgpu-fan";
+  version = "0.0.6";
+
+  src = fetchFromGitHub {
+    repo = pname;
+    owner = "chestm007";
+    rev = version;
+    sha256 = "1ngfrk6agk8wz0q9426lwrqhbgxc98hrsv0kn6wgz25j1rv9332b";
+  };
+
+  propagatedBuildInputs = with python3Packages; [
+    numpy
+    pyyaml
+  ];
+
+  meta = with stdenv.lib; {
+    description = "Fan controller for AMD graphics cards running the amdgpu driver on Linux";
+    homepage = "https://github.com/chestm007/amdgpu-fan";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+  };
+}

pkgs/tools/misc/radeon-profile-daemon/default.nix

@@ -0,0 +1,35 @@
+{ stdenv
+, fetchFromGitHub
+
+, qtbase
+, qmake
+}:
+
+stdenv.mkDerivation rec {
+  pname = "radeon-profile-daemon";
+  version = "20190603";
+
+  nativeBuildInputs = [ qmake ];
+  buildInputs = [ qtbase ];
+
+  src = (
+    fetchFromGitHub {
+      owner = "marazmista";
+      repo = "radeon-profile-daemon";
+      rev = version;
+      sha256 = "06qxq2hv3l9shna8x5d9awbdm9pbwlc6vckcr63kf37rrs8ykk0j";
+    }
+  ) + "/radeon-profile-daemon";
+
+  preConfigure = ''
+    substituteInPlace radeon-profile-daemon.pro \
+      --replace "/usr/" "$out/"
+  '';
+
+  meta = with stdenv.lib; {
+    description = "System daemon for reading current clocks of AMD Radeon cards";
+    homepage = "https://github.com/marazmista/radeon-profile-daemon";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+  };
+}

pkgs/tools/misc/samrewritten/default.nix

@@ -0,0 +1,59 @@
+{ stdenv
+, fetchFromGitHub
+, makeWrapper
+
+, curl
+, gnumake
+, gnutls
+, gtk3
+, gtkmm3
+, pkg-config
+, yajl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "SamRewritten";
+  version = "2.0";
+
+  src = fetchFromGitHub {
+    owner = "PaulCombal";
+    repo = pname;
+    rev = "202005";
+    sha256 = "0zcb6cmzk4fvbf0rkyyfvlnh9mhi0wz89parprkz6vxrj65ph1f6";
+  };
+
+  nativeBuildInputs = [ gnumake pkg-config ];
+  buildInputs = [
+    curl
+    gnutls
+    gtk3
+    gtkmm3
+    yajl
+  ];
+
+  NIX_CFLAGS_LINK = "-pthread";
+
+  # FIXME: Use `make install` after the next release
+  # FIXME: Get `substituteInPlace` working
+  installPhase = ''
+    mkdir -p $out/lib/SamRewritten/{bin,glade,assets}
+    mkdir -p $out/share/icons/hicolor/{64x64,256x256}/apps
+    mkdir -p $out/share/applications
+    mkdir -p $out/bin
+    cp bin/launch.sh bin/samrewritten bin/libsteam_api.so $out/lib/SamRewritten/bin/
+    ln -s $out/lib/SamRewritten/bin/launch.sh $out/bin/samrewritten
+    cp glade/main_window.glade $out/lib/SamRewritten/glade/main_window.glade
+    cp assets/icon_64.png $out/share/icons/hicolor/64x64/apps/samrewritten.png
+    cp assets/icon_256.png $out/share/icons/hicolor/256x256/apps/samrewritten.png
+    cp assets/icon_256.png $out/lib/SamRewritten/assets/
+
+    substitute package/samrewritten.desktop $out/share/applications/samrewritten.desktop \
+      --replace /usr/bin/samrewritten $out/bin/samrewritten
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Steam Achievement Manager For Linux";
+    homepage = "https://github.com/PaulCombal/SamRewritten";
+    license = licenses.gpl3;
+  };
+}

pkgs/tools/misc/spotify-ripper/default.nix

@@ -0,0 +1,100 @@
+{ stdenv
+, fetchFromGitHub
+
+, python2Packages
+
+, aacSupport ? false, faac
+, alacSupport ? false, libav
+, flacSupport ? false, flac
+, m4aSupport ? false, mp4Support ? false, fdk-aac-encoder
+, oggSupport ? false, vorbisTools
+, opusSupport ? false, opusTools
+}:
+
+assert aacSupport               -> faac.meta.available;
+assert alacSupport              -> libav.meta.available;
+assert flacSupport              -> flac.meta.available;
+assert m4aSupport || mp4Support -> fdk-aac-encoder.meta.available;
+assert oggSupport               -> vorbisTools.meta.available;
+assert opusSupport              -> opusTools.meta.available;
+
+let
+
+  lockPackage =
+    { package
+    , version
+    , sha256
+    , extra ? (oldAttrs: { })
+    }: package.overrideAttrs (oldAttrs: rec {
+      inherit version;
+      src = python2Packages.fetchPypi {
+        inherit (oldAttrs) pname;
+        inherit version sha256;
+      };
+    } // extra oldAttrs);
+
+  colorama = lockPackage {
+    package = python2Packages.colorama;
+    version = "0.3.3";
+    sha256 = "1716z9pq1r5ys3nkg7wdrb3h2f9rmd0zdxpxzmx3bgwgf6xg48gb";
+  };
+
+  mutagen = lockPackage {
+    package = python2Packages.mutagen;
+    version = "1.30";
+    sha256 = "0kv2gjnzbj1w0bswmxm7wi05x6ypi7jk52s0lb8gw8s459j41gyd";
+    extra = oldAttrs: {
+      patches = [ ];
+    };
+  };
+
+  pyspotify = lockPackage {
+    package = python2Packages.pyspotify;
+    version = "2.0.5";
+    sha256 = "0y16c024rrvbvfdqj1n0k4b25b1nbza3i7kspg5b0ci2src1rm7v";
+  };
+
+in
+
+python2Packages.buildPythonApplication rec {
+  pname = "spotify-ripper";
+  version = "2016.12.31";
+
+  src = fetchFromGitHub {
+    owner = "hbashton";
+    repo = pname;
+    rev = "d0464193dead7bd3ac7580e98bde86a0f323acae";
+    sha256 = "003d6br20f1cf4qvmpl62bk0k4h4v66ib76wn36c23bnh9x5q806";
+  };
+
+  propagatedBuildInputs = [
+    colorama
+    mutagen
+    pyspotify
+    python2Packages.requests
+    python2Packages.schedule
+    python2Packages.setuptools
+
+    (if flacSupport then flac else null)
+    (if alacSupport then libav else null)
+    (if aacSupport then faac else null)
+    (if (m4aSupport || mp4Support) then fdk-aac-encoder else null)
+    (if oggSupport then vorbisTools else null)
+    (if opusSupport then opusTools else null)
+  ];
+
+  # Remove impure executables.
+  patches = [ ./fix-setup.patch ];
+
+  meta = {
+    description = "Rip Spotify URIs to audio files, including ID3 tags and cover art";
+    longDescription = ''
+      Spotify-ripper is a small ripper script for Spotify that rips Spotify URIs
+      to audio files and includes ID3 tags and cover art. By default
+      spotify-ripper will encode to MP3 files, but includes the ability to rip
+      to WAV, FLAC, Ogg Vorbis, Opus, AAC, and MP4/M4A.
+    '';
+    homepage = "https://github.com/hbashton/spotify-ripper";
+    license = stdenv.lib.licenses.mit;
+  };
+}

pkgs/tools/misc/spotify-ripper/fix-setup.patch

@@ -0,0 +1,28 @@
+diff --git a/setup.py b/setup.py
+index a800b3b..8967921 100755
+--- a/setup.py
++++ b/setup.py
+@@ -22,14 +22,13 @@ setup(
+     name='spotify-ripper',
+     version='2.9.1',
+     packages=find_packages(exclude=["tests"]),
+-    scripts=['spotify_ripper/main.py'],
+     include_package_data=True,
+     zip_safe=False,
+ 
+     # Executable
+     entry_points={
+         'console_scripts': [
+-            'spotify-ripper = main:main',
++            'spotify-ripper = spotify_ripper.main:main',
+         ],
+     },
+ 
+@@ -67,7 +66,5 @@ setup(
+         'Programming Language :: Python :: 3',
+         'Programming Language :: Python :: 3.4',
+     ],
+-    long_description=_read('README.rst'),
+ )
+ 
+-create_default_dir()